Тиристоры

Рассмотрим несколько моделей тиристоров разной сложности.

Простейшая модель тиристора. Она состоит из диода D, на который подается управляющее напряжение Vупр, и нелинейной проводимости GN, коммутируемой током I, протекающим через диод (рис. 5.11)

.subckt SRC1   1   2   3

.FUNC GN(I) TABLE(I,-100,1e-6,0.2,1e-6,0.21,1e3,100,1e3) 

R   1  4  2.5

D   3  4  DD

VD  3  1  DC=0

G   2   1   VALUE={GN(I(VD))*V(3,4)}

.model   DD    D (IS=1e-14  N=2)

.ends

Рис. 5.11. Простейшая модель тиристора

В версиях Design Center до 6.1 описание нелинейной проводимости в виде функции GN приходится, к сожалению, помещать в задание на моделирование конкретной схемы, так как по правилам PSpice 5 внутри описания макромоделей допускается помещать только директивы .MODEL.

При отсутствии управляющего сигнала диод закрыт и проводимость GN=1 мкСм. При подаче управляющего сигнала диод открывается и проводимость GN резко возрастает до 1000 См. После снятия управляющего напряжения диод остается открытым, запирается он после подачи обратного управляющего напряжения.

Транзисторная модель тиристора

показана на рис. 5.12. Она повторяет реальную схему имитации тиристора с помощью двух транзисторов противоположной проводимости. Приведем пример такой модели:

.subckt SRC2 1 2 3

Q1   2   4   1   KT818

Q2   4   2   3   KT819

R     2   3   10

.model   KT818   PNP (Is=1e-12 Bf=100 Vaf=50 Rb=10)

.model   KT819  AKO:KT818  NPN

.ends

Рис. 5.12. Двухтранзисторная модель тиристора

Эта модель достаточно точная, с ее помощью имитируются кривые гистерезиса тиристора, но она требует больших объемов вычислений, чем приведенная ниже более простая диодная модель.

Диодная модель тиристора

(рис. 5.13) имеет вид [5, 31, 32]:

.subckt SRC3   1   2   3

RS   1   4   0.5

RA   4   5   1e6

RC   5   9   1e8

RK   9   3   1e6

RG   2   9   300

DA   4   8   DA

DC   9   5   DC

DK   9   7   DK

VA   8   5   DC=0

VK   7   3   DC=0

FC   5   9   POLY(2)   VA   VK   0.0   0.98   0.95

.model   DA   D (Is=10f Cjo=0p Tt=0n Vj=0.65 M=0.3)

.model   DC   D (Is=10f Cjo=0p Tt=0n Vj=0.65 M=0.3)

.model   DK   D (Is=10f Cjo=0p Tt=0n Vj=1.4 M=0.5)

.ends

Рис. 5.13. Диодная модель тиристора

Модель состоит из трех полупроводниковых диодов, в которых при необходимости учитываются емкости переходов. Зависимый источник тока FC, управляемый напряжениями переходов, отображает усиление инжекционных токов диодов. Наличие резисторов RA, RC и RK

позволяет моделировать тиристор в режиме семистора.

Макромодель тиристора, принятая в PSpice, помещена в библиотеку thyrist.lib.


Содержание раздела

---

---